FINISH
/clear
/PREP7

!body ram+vidlice
K,1,403.98,0,0, 
K,2,0,70,65,
K,3,0,70,-65,
K,4,267.65,460.23,0,
K,5,789.98,588,0,
K,6,838.57,440.81,0,
K,7,838.57,440.81,50,
K,8,838.57,440.81,-50,
K,9,1005,70,50,
K,10,1005,70,-50,

!body kvuli ztenceni trubek
K,11,398.24,492.18,0,
K,12,659.4,556.06,0,
K,13,301.73,345.18,0,
K,14,369.9,115.06,0,
K,15,512.63,110.2,0,
K,16,729.93,330.61,0,

!mustek zadni celisti
K,17,188.47,344.78,-19.2        
K,18,188.47,344.78,19.2         
K,19,188.47,344.78,0             

!trubky
L,1,2      !1
L,1,3      !2
L,1,14     !3
L,14,13    !4
L,13,4     !5
L,4,11     !6
L,11,12    !7
L,12,5     !8
L,5,6      !9
L,6,8      !10
L,6,7      !11
L,8,10     !12
L,7,9      !13
L,1,15     !14
L,15,16    !15
L,16,6     !16
L,9,10     !17
L,2,3      !18
L,17,19    !19
L,18,19    !20
L,3,17     !21
L,17,4     !22
L,4,18     !23
L,18,2     !24
 
!tvorba prvku
ET,1,BEAM188

!prurezy prvku beam
SECTYPE,   1, BEAM, CTUBE, chain_stay, 0          
SECOFFSET, CENT 
SECDATA,9,11,0,0,0,0,0,0,0,0,0,0 

SECTYPE,   2, BEAM, CTUBE, seat_stay, 0        
SECOFFSET, CENT 
SECDATA,9,11,0,0,0,0,0,0,0,0,0,0

SECTYPE,   3, BEAM, CTUBE, head_tube, 0     
SECOFFSET, CENT 
SECDATA,17,20,0,0,0,0,0,0,0,0,0,0

SECTYPE,   4, BEAM, CTUBE, leva_top, 0          
SECOFFSET, CENT 
SECDATA,17,19,0,0,0,0,0,0,0,0,0,0 

SECTYPE,   5, BEAM, CTUBE, stred_top, 0           
SECOFFSET, CENT 
SECDATA,17.5,19,0,0,0,0,0,0,0,0,0,0  

SECTYPE,   6, BEAM, CTUBE, prava_top, 0          
SECOFFSET, CENT 
SECDATA,17,19,0,0,0,0,0,0,0,0,0,0  

SECTYPE,   7, BEAM, CTUBE, horni_seat, 0         
SECOFFSET, CENT 
SECDATA,15.5,17.5,0,0,0,0,0,0,0,0,0,0 

SECTYPE,   8, BEAM, CTUBE, stred_seat, 0         
SECOFFSET, CENT 
SECDATA,16,17.5,0,0,0,0,0,0,0,0,0,0 

SECTYPE,   9, BEAM, CTUBE, dolni_seat, 0           
SECOFFSET, CENT 
SECDATA,15.5,17.5,0,0,0,0,0,0,0,0,0,0 

SECTYPE,   10, BEAM, CTUBE, leva_down, 0           
SECOFFSET, CENT 
SECDATA,20,22,0,0,0,0,0,0,0,0,0,0

SECTYPE,   11, BEAM, CTUBE, stred_down, 0          
SECOFFSET, CENT 
SECDATA,20.5,22,0,0,0,0,0,0,0,0,0,0

SECTYPE,   12, BEAM, CTUBE, prava_down, 0          
SECOFFSET, CENT 
SECDATA,20,22,0,0,0,0,0,0,0,0,0,0

SECTYPE,   13, BEAM, CSOLID,quick_release, 0
SECOFFSET, CENT 
SECDATA,2.5,0,0,0,0,0,0,0,0,0,0,0 

SECTYPE,   14, BEAM, HREC, fork_top, 0
SECOFFSET, CENT 
SECDATA,36,50,2,2,2,2,0,0,0,0,0,0

SECTYPE,   15, BEAM, HREC, fork_leg, 0
SECOFFSET, CENT 
SECDATA,50,10,2,2,2,2,0,0,0,0,0,0  

!slitina hliniku na ram a vidlici
MPTEMP
MPTEMP,1,0  
MPDATA,EX,1,,70000  
MPDATA,PRXY,1,,0.33

!ocel na rychloupinaky
MPTEMP  
MPTEMP,1,0  
MPDATA,EX,2,,200000 
MPDATA,PRXY,2,,0.28

!prirazeni prvku k trubkam
!chain stay
LSELL,S,,,1
LATT,1, ,1, , , ,1 

LSELL,S,,,2
LATT,1, ,1, , , ,1

!seat stay
LSELL,S,,,19               
LATT,1, ,1, , , ,2

LSELL,S,,,20               
LATT,1, ,1, , , ,2

LSELL,S,,,21
LATT,1, ,1, , , ,2

LSELL,S,,,22
LATT,1, ,1, , , ,2

LSELL,S,,,23
LATT,1, ,1, , , ,2

LSELL,S,,,24
LATT,1, ,1, , , ,2

!head tube
LSELL,S,,,9
LATT,1, ,1, , , ,3

!leva top
LSELL,S,,,6
LATT,1, ,1, , , ,4

!stred top
LSELL,S,,,7
LATT,1, ,1, , , ,5

!prava top
LSELL,S,,,8
LATT,1, ,1, , , ,6

!horni seat
LSELL,S,,,5
LATT,1, ,1, , , ,7

!stred seat
LSELL,S,,,4
LATT,1, ,1, , , ,8

!dolni seat
LSELL,S,,,3
LATT,1, ,1, , , ,9

!leva down
LSELL,S,,,14
LATT,1, ,1, , , ,10

!stred down
LSELL,S,,,15
LATT,1, ,1, , , ,11

!prava down
LSELL,S,,,16
LATT,1, ,1, , , ,12

!quick release
LSELL,S,,,17
LATT,2, ,1, , , ,13    

LSELL,S,,,18
LATT,2, ,1, , , ,13     
                               
!fork top
LSELL,S,,,10
LATT,1, ,1, , , ,14

LSELL,S,,,11
LATT,1, ,1, , , ,14

!fork leg
LSELL,S,,,12
LATT,1, ,1, , , ,15

LSELL,S,,,13
LATT,1, ,1, , , ,15

!vyber vsech trubek
LSELL,ALL

!volba dlky prvku
LESIZE,ALL,0.15, , , ,1, , ,1,
                                           
! nasitovani
LMESH, ALL

! vazby
DK,2,UY
DK,3,UY
DK,3,UZ
DK,9,UX
DK,9,UY
DK,10,UX
DK,10,UY
DK,10,UZ

!sily od cyklisty
FK,4,FX,-593
FK,4,FY,-498
FK,4,MZ,177455
FK,5,FX,593
FK,5,FY,-216
FK,5,MZ,-73985
FK,1,FY,-147

!zatizeni od brzdeni
FK,6,FX,146
FK,6,FY,36
FK,6,MZ,6065
FK,19,FX,194
FK,19,FY,-112
FK,19,MZ,9072

/SOLU
ANTYPE,0

SOLVE

!pocet uzlu a prvku
*get,n_max,node,,num,max  
*get,n_max,elem,,num,max


  
