/prep7

ET,1,MASS21		!* prvek hmotnost
ET,2,COMBIN39	!* prvek nelineární pružina
ET,3,COMBIN39	!* prvek nelineární pružina
ET,4,BEAM189	!* nosníkový prvek
ET,5,PIPE16		!* prvek pro disk

KEYOPT,2,3,2	!* Nastavení DOF pružiny 2 na UY
KEYOPT,3,3,3	!* Nastavení DOF pružiny 3 na UZ

MP,EX,1,2.1e11 		!* younguv modul pruznosti v tahu
MP,PRXY,1,0.3		!* poissonovo cislo
MP,DENS,1,7800		!* hustota oceli
MP,DAMP,1,.1e11		!* tlumení pružiny (konst)

!* zatěžovací křivka pružiny
K1=1e2			!* Konst. tuhosti 1
m1sc=1e-3		!* měřítko pro graf tuhosti
R,1,-1.5*m1sc,-3.375*K1,-0.9*m1sc,-0.725*K1,-0.5*m1sc,-0.125*K1
RMORE,0.0,0.0,.5*m1sc,.125*K1,.9*m1sc,.725*K1 
RMORE,1.5*m1sc,3.375*K1,2*m1sc,8*K1,3*m1sc,27*K1   
RMORE,4*m1sc,64*K1,5*m1sc,125*K1,6*m1sc,216*K1 
RMORE,7*m1sc,343*K1,8*m1sc,512*K1

!* vlastnosti beamu
SECTYPE,   1, BEAM, CSOLID, , 0 
SECOFFSET, CENT 
SECDATA,0.005,0,0,0,0,0,0,0,0,0 

!* vlastnosti hmotnosti
R,2,.02,.02,.02,.00002,.0000,.0000

!* vlastnosti pipe
R,3,.35,.175

!* vlastnosti inerciální soustavy
OMEGA,55,0,0		!* úhlová rychlost soustavy
DOMEGA,0.5,0,0, 	!* úhlové zrychlení soustavy
CORIOLIS,ON,,,ON	!* uvažujeme koriolisovy efekty

!* načtení ze souboru do tabulky
*DIM,Tt2,TABLE,9,1,1,Eps,f,
*TREAD,Tt2,biax,txt,

!* načtení ze souboru do pole



!*********************************************************
!* geometrie pro rotor v ložiscích a s jedním diskem     *
!*********************************************************

/PREP7
K,1,,,, 
K,2,1,,,
K,3,.5,,
LSTR,1,3    !* vytvoří přímou line mezi dvěma kpointy.
LSTR,3,2
LESIZE,1,,,5
LESIZE,2,,,5
TYPE,4   
MAT,1
REAL,1   
ESYS,0   
SECNUM,1 
LMESH,1,2
/ESHAPE,1.0 
/EFACET,1 
/REPLOT

!* zabráníme protáčení hřídele a posuvům v axiálním směru
D,ALL,UX
D,ALL,ROTX

!* Přidání nodů pro pružiny
N,22,0,0,0
N,23,1,0,0
N,24,0.05,0,0
N,25,0.95,0,0

D,22, , , , , ,UX,UY,UZ
D,23, , , , , ,UX,UY,UZ
D,24, , , , , ,UX,UY,UZ
D,25, , , , , ,UX,UY,UZ

!* Přidání elementů pružiny ve vertikálním směru
TYPE,   2   
MAT,    1
REAL,   1   
ESYS,   0   
SECNUM, 1 
TSHAP,LINE  
E,1,22
E,12,23
E,3,24
E,21,25

!* Přidání elementů pružiny v horizontálním směru
TYPE,   3   
MAT,    1
REAL,   1   
ESYS,   0   
SECNUM, 1 
TSHAP,LINE  
E,1,22
E,12,23
E,3,24
E,21,25

!* přidání elementu hmotnosti jako nevývahy
TYPE,   1   
MAT,    1
REAL,   2  
ESYS,   0   
SECNUM, 1 
TSHAP,LINE
E,2

!* vložení disku
N,26,.52,0
TYPE,   5   
MAT,    1
REAL,   3  
ESYS,   0   
SECNUM, 1 
TSHAP,LINE
E,2,26
CP,1,ALL,2,26,

!*************************************************
!* Tranzientní analýza                           *
!*************************************************
/SOL
ANTYPE,STATIC
NSUBST,10,0,0
/SOL
ANTYPE,TRANS 
TRNOPT,FULL 
LUMPM,0  
DELTIM,0.5,0,0  
OUTRES,ERASE
OUTRES,ALL,ALL  
TIME,120  
OMEGA,1000
OUTPR,NSOL,ALL,
/STATUS,SOLU
SOLVE   

!*************************************************
!* Modální analýza + campbellův diagram          *
!*************************************************
/SOL  
ANTYPE,MODAL 
MODOPT,QRDAMP,8,
EQSLV,SPAR  
MXPAND,8
LUMPM,0 
PSTRES,OFF
CORIOLIS,ON,,,ON
CAMPBELL,ON 
OMEGA,0
/STATUS,SOLU
SOLVE 
MXPAND,8
OMEGA,10000
CORIOLIS,ON,,,ON
CAMPBELL,ON 
/STATUS,SOLU
SOLVE
 
/post1
PLCAMP,ON

/post26
RESP,,		!* mělo by vykreslit FFT 
