# Otevře dialogové okno pro načtení zdrojového signálu
fileName$ = chooseReadFile$: "Zvolte zdrojový signál"
# Pokud nebylo zadáno jméno souboru, ukonči skript s chybovou hláškou
if fileName$ = ""
	exitScript: "Nezadali jste žádný zdrojový signál,"
	...+ " výkon skriptu byl zastaven!"
# V opačném případě načti soubor podle zadaného jména a cesty
else
	Read from file: fileName$
endif
# Do proměnné 'soundfile$' ulož jméno zpracovávaného souboru
soundfile$ = selected$("Sound")


# Funkce formantové analýzy
	# 1.parametr: Časový krok (0 = auto, tj. 25% délky okna)
	# mezi středy sousedních oken
	# 2.parametr: Max. počet (hledaných) formantů
	# 3.parametr: Max. frek. nejvyššího formantu
	# 4.parametr: Délka okna
	# 5.parametr: Frek. začátku preemfáze
To Formant (burg): 0.02, 5, 5000, 0.02, 50


# Vytvoření nové tabulky, sloužící jako výstup
Down to Table: "no", "yes", 6, "no", 3, "no", 3, "no"
# Úprava tabulky
undef$ = "--undefined--"
vzorec$ = "if string$(self) = undef$ then 0 else self endif"
Formula (column range): "F1(Hz)", "F5(Hz)", vzorec$


# Otevře dialogové okno pro uložení textové souboru
fileName$ = chooseWriteFile$: "Uložit informační textový soubor",
... "Speaker_3for.txt"
# Pokud bylo zadáno jméno souboru, ulož soubor...
if fileName$ <> ""
	Save as comma-separated file: fileName$
# V opačném případě ukonči skript s chybovou hláškou
else
	exitScript: "Nezadali jste jméno textového souboru,"
	...+ " výstup nebyl uložen!"
endif