# Otevře dialogové okno pro načtení zdrojového signálu
fileName$ = chooseReadFile$: "Zvolte zdrojový signál"
# Pokud nebylo zadáno jméno souboru, ukonči skript s chybovou hláškou
if fileName$ = ""
	exitScript: "Nezadali jste žádný zdrojový signál,"
	...+ " výkon skriptu byl zastaven!"
# V opačném případě načti soubor podle zadaného jména a cesty
else
	Read from file: fileName$
endif
# Do proměnné 'soundfile$' ulož jméno zpracovávaného souboru
soundfile$ = selected$("Sound")



# Sekvence příkazů tvořící výst. signál
select Sound 'soundfile$'
vzorkovaci_frek = Get sampling frequency
To Pitch (cc): 0, 75, 15, "no", 0.03, 0.45, 0.01, 0.35, 0.14, 250
plus Sound 'soundfile$'
To PointProcess (cc)
To Sound (phonation): vzorkovaci_frek, 0.6, 0.05, 0.7, 0.03, 3, 4
Scale peak: 1
plus Sound 'soundfile$'
Combine to stereo



# Otevře dialogové okno pro uložení výstupního souboru
fileName$ = chooseWriteFile$: "Uložit výstupní dvoukanálový"
...+ " signál jako WAV soubor", "Speaker_2glot.wav"
# Pokud bylo zadáno jméno souboru, ulož soubor...
if fileName$ <> ""
	select Sound 'soundfile$'
	Save as WAV file: fileName$
# V opačném případě ukonči skript s chybovou hláškou
else
	exitScript: "Nezadali jste jméno výstupního souboru,"
	...+ " signál nebyl uložen!"
endif



# Získání počtu pulzů v signálu do proměnné pocet_bodu
soundfileLong$ = soundfile$ + "_" + soundfile$
select PointProcess 'soundfileLong$'
pocet_bodu = Get number of points
# Vytvoření nové tabulky, sloužící jako výstup
Create Table with column names: "Tabulka", pocet_bodu, "Cas Hodnota"
# Cyklus zapisující do tabulky řádek po řádku
for akt_bod from 1 to pocet_bodu
	select PointProcess 'soundfileLong$'
	# Získání přesného okamžiku pulzu
	cas = Get time from index: akt_bod
	select Sound 'soundfileLong$'
	# Získání hodnoty signálu v místě pulzu
	hodnota = Get value at time: 1, cas, "Nearest"
	# Vložení hodnot do tabulky
	select Table Tabulka
  	Set numeric value: akt_bod, "Cas", cas
	Set numeric value: akt_bod, "Hodnota", hodnota
endfor


# Otevře dialogové okno pro uložení textové souboru
fileName$ = chooseWriteFile$: "Uložit informační textový soubor",
... "Speaker_2pulse.txt"
# Pokud bylo zadáno jméno souboru, ulož soubor...
if fileName$ <> ""
	select Table Tabulka
	Save as comma-separated file: fileName$
# V opačném případě ukonči skript s chybovou hláškou
else
	exitScript: "Nezadali jste jméno textového souboru,"
	...+ " výstup nebyl uložen!"
endif